Fortran-dynamic-arrays

Fortran-動的配列

• 動的配列*は、コンパイル時にはサイズが不明ですが、実行時には既知の配列です。

動的配列は、 allocatable 属性で宣言されます。

例えば、

real, dimension (:,:), allocatable :: darray

ただし、そのような配列にメモリを割り当てるには、 allocate 関数を使用して、配列のランク、つまり次元を指定する必要があります。

allocate ( darray(s1,s2) )

配列が使用された後、プログラムで、作成されたメモリは deallocate 関数を使用して解放する必要があります

deallocate (darray)

例

次の例は、上記の概念を示しています。

program dynamic_array
implicit none

   !rank is 2, but size not known
   real, dimension (:,:), allocatable :: darray
   integer :: s1, s2
   integer :: i, j

   print*, "Enter the size of the array:"
   read*, s1, s2

   ! allocate memory
   allocate ( darray(s1,s2) )

   do i = 1, s1
      do j = 1, s2
         darray(i,j) = i*j
         print*, "darray(",i,",",j,") = ", darray(i,j)
      end do
   end do

   deallocate (darray)
end program dynamic_array

上記のコードをコンパイルして実行すると、次の結果が生成されます-

Enter the size of the array: 3,4
darray( 1 , 1 ) = 1.00000000
darray( 1 , 2 ) = 2.00000000
darray( 1 , 3 ) = 3.00000000
darray( 1 , 4 ) = 4.00000000
darray( 2 , 1 ) = 2.00000000
darray( 2 , 2 ) = 4.00000000
darray( 2 , 3 ) = 6.00000000
darray( 2 , 4 ) = 8.00000000
darray( 3 , 1 ) = 3.00000000
darray( 3 , 2 ) = 6.00000000
darray( 3 , 3 ) = 9.00000000
darray( 3 , 4 ) = 12.0000000

データ文の使用

*data* ステートメントは、複数の配列の初期化、または配列セクションの初期化に使用できます。

データ文の構文は次のとおりです-

data variable/list/...

例

次の例は、概念を示しています-

program dataStatement
implicit none

   integer :: a(5), b(3,3), c(10),i, j
   data a/7,8,9,10,11/

   data b(1,:)/1,1,1/
   data b(2,:)/2,2,2/
   data b(3,:)/3,3,3/
   data (c(i),i = 1,10,2)/4,5,6,7,8/
   data (c(i),i = 2,10,2)/5*2/

   Print *, 'The A array:'
   do j = 1, 5
      print*, a(j)
   end do

   Print *, 'The B array:'
   do i = lbound(b,1), ubound(b,1)
      write(*,*) (b(i,j), j = lbound(b,2), ubound(b,2))
   end do

   Print *, 'The C array:'
   do j = 1, 10
      print*, c(j)
   end do

end program dataStatement

上記のコードをコンパイルして実行すると、次の結果が生成されます-

 The A array:
           7
           8
           9
          10
          11
 The B array:
           1           1           1
           2           2           2
           3           3           3
 The C array:
           4
           2
           5
           2
           6
           2
           7
           2
           8
           2

Whereステートメントの使用

*where* ステートメントを使用すると、論理条件の結果に応じて、式で配列の一部の要素を使用できます。 指定された条件が真の場合、要素で式を実行できます。

例

次の例は、概念を示しています-

program whereStatement
implicit none

   integer :: a(3,5), i , j

   do i = 1,3
      do j = 1, 5
         a(i,j) = j-i
      end do
   end do

   Print *, 'The A array:'

   do i = lbound(a,1), ubound(a,1)
      write(*,*) (a(i,j), j = lbound(a,2), ubound(a,2))
   end do

   where( a<0 )
      a = 1
   elsewhere
      a = 5
   end where

   Print *, 'The A array:'
   do i = lbound(a,1), ubound(a,1)
      write(*,*) (a(i,j), j = lbound(a,2), ubound(a,2))
   end do

end program whereStatement

上記のコードをコンパイルして実行すると、次の結果が生成されます-

 The A array:
           0           1           2           3           4
          -1           0           1           2           3
          -2          -1           0           1           2
 The A array:
           5           5           5           5           5
           1           5           5           5           5
           1           1           5           5           5