Arduino-humidity-sensor

Arduino-湿度センサー

このセクションでは、Arduinoボードをさまざまなセンサーと接続する方法を学習します。 私たちは次のセンサーについて説明します-

• 湿度センサー（DHT22）
• 温度センサー（LM35）
• 水検知センサー（簡易水トリガー）
• PIRセンサー
• 超音波センサー
• GPS

湿度センサー（DHT22）

DHT-22（AM2302とも呼ばれる）は、デジタル出力、相対湿度、温度センサーです。 容量性湿度センサーとサーミスターを使用して周囲の空気を測定し、データピンにデジタル信号を送信します。

この例では、このセンサーをArduino UNOで使用する方法を学習します。 室温と湿度がシリアルモニターに出力されます。

DHT-22センサー

DHT-22センサー

接続は簡単です。 左の最初のピンは3〜5V電源、2番目のピンはデータ入力ピン、右端のピンはグランドです。

技術的な詳細

• 電源-3-5V
• 最大電流-2.5mA
• 湿度-0-100％、2-5％の精度
• 温度-40〜80°C、±0.5°Cの精度

必要なコンポーネント

次のコンポーネントが必要になります-

• 1×ブレッドボード
• 1×Arduino Uno R3
• 1×DHT22 *1×10Kオーム抵抗

手順

以下の画像に示すように、回路図に従って、ブレッドボード上のコンポーネントを接続します。

湿度センサー回路接続

湿度センサーブレッドボード

スケッチ

コンピューターでArduino IDEソフトウェアを開きます。 Arduino言語でコーディングすると、回路が制御されます。 [新規]をクリックして、新しいスケッチファイルを開きます。

スケッチ

Arduinoコード

//Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2//what digital pin we're connected to
//Uncomment whatever type you're using!
//#define DHTTYPE DHT11//DHT 11
#define DHTTYPE DHT22//DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21//DHT 21 (AM2301)
//Connect pin 1 (on the left) of the sensor to +5V
//NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
//to 3.3V instead of 5V!
//Connect pin 2 of the sensor to whatever your DHTPIN is
//Connect pin 4 (on the right) of the sensor to GROUND
//Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
//Initialize DHT sensor.
//Note that older versions of this library took an optional third parameter to
//tweak the timings for faster processors. This parameter is no longer needed
//as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000);//Wait a few seconds between measurements
   float h = dht.readHumidity();
  //Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
  //Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
  //Read temperature as Fahrenheit (isFahrenheit = true)
  //Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }

  //Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
  //Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print ("* C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

注意すべきコード

DHT22センサーには、次のようにボードに接続される4つの端子（V〜cc〜、DATA、NC、GND）があります-

• DATAピンからArduinoピン番号2
• V〜cc〜ピンから5ボルトのArduinoボード
• ArduinoボードのグランドへのGNDピン
• DATAとV〜cc〜ピンの間に10kオームの抵抗（プルアップ抵抗）を接続する必要があります

ハードウェア接続が完了したら、前述のとおり、DHT22ライブラリをArduinoライブラリファイルに追加する必要があります。

結果

シリアルポートモニターに温度と湿度が表示され、2秒ごとに更新されます。